Bell’s Inequality

Transcribed from the printed issue; not yet reviewed. Read it in the PDF of the issue, page 73

Intellectual communication with my daughter, Alison, became difficult some years ago when I realized that mathematical expressions which I would describe as ‘smeared all over the page’ held some meaning for her but none for me. My degree is in philosophy: she is just starting her final year in physics – although she did give a passing nod of recognition to philosophy as one of the side-shows in her first year. This explains how I came to browse among the philosophy and physics shelves in the bookshops of London, Oxford and Bristol and so added to my obsession with APL another with the philosophical problems of physics in general and quantum physics in particular. So, for those among VECTOR readers who enjoy philosophical in-fighting, here is an account of one of the books I found and how I came to use APL to help in thinking about the problem it expounds.

I knew I was hooked after reading ‘Quantum Reality’. Nick Herbert is a professional physicist writing a popular account of how physicists came to ‘lose their grip on reality’. He conveys the essence of the problem without resort to mathematics and follows it with a robust account of the various bizarre and incompatible models proposed by eminent physicists to give substance to the mathematical formalism on which they all were and are agreed. Perhaps I warm to Nick Herbert because he is not awed by Von Neumann’s analysis; even going so far as to suggest a similarity with a cartoon showing a mathematician before a blackboard on which there is ‘the usual incomprehensible symbols but near the end there is a gap in which he’s written, “And then a miracle occurs”. The math then resumes and proceeds to its logical conclusion. The mathematicians colleague is pointing to the gap and saying, “I think you should be more explicit here in Step 2”.’

Nick Herbert relates how he finished his formal education, ‘Blissfully ignorant concerning the real issues surrounding the quantum reality question’ until in 1970 he was shown a paper by John Bell expounding a theorem of which he says, ‘Bell’s theorem is easy to understand but hard to believe. This theorem says that reality must be non-local. “Non-local” means, . . . . . . . . , that the atom’s measured attributes are determined not just by events happening at the actual measurement site but by events arbitrarily distant, including events outside the light cone – that is events so far away that to reach the measurement site their influence must travel faster than light.’ What is more, says Herbert, this theorem is expressed in simple arithmetic and, even more confounding, the test for non-locality suggested by it has been made and is confirmed by the experiments.

So I came to the chapter that expounds Bell’s theorem and tried (and failed) to understand its significance. What I needed was a model in which I could point to the exact place at which ‘the miracle occurs’. I set the model up and then re-opened communication with my daughter by means of the letter reproduced below together with the simulated results of the tests of reality that Bell had proposed – is it classical (Newtonian) or quantum (non-local)? As you will see, the APL I used to set up the model is very simple being used simply as a tool of thought.

Boxing Day 1986

Dear Alison, About 18 months ago – I believe on the occasion of the British APL Association AGM in the Spring of 1985 – I bought several books in Dillon’s which fall into the category of popularisations of the concepts of quantum physics. In particular they analyse the difficulty that arises in the interpretation of the experimental evidence (& the mathematical underpinning) of models of quantum systems based on particles as opposed to models based on waves. I found that the book by a physicist, Nick Herbert, called ‘Quantum Reality’ was the clearest explanation of the difficulty. He explains that he wrote the book to bring to a wider public the findings of some comparatively recent experiments by Alain Aspect. These experiments were performed because a paper by the theoretical physicist, J.S. Bell, suggested how the hypothesis of non-local effects might be tested. This is a development of the ‘thought experiments’ which Einstein proposed among others when the unexpected and, to Einstein, unacceptable consequences of the mathematical formalism of quantum effects was realised.

The thought experiments are concerned with measurements of the characteristics of pairs of particles which can be generated in what is called a ‘phase-entangled’ state. According to Nick Herbert this means that these particles can be considered to be twins – identical in all their characteristics. Two beams of these particles can be directed at meters which can be any distance apart and any distance from the particle source. The particle characteristic which is measured is polarity and each meter can measure one of two conditions, ‘up’ and ‘down’. However, the meter can measure polarity in several planes. Bell suggested that polarity should be measured at -30, 0 & 30 degrees and that comparisons be made between the results at the meters with both set at 0, one at 0 with the other at -30 or 30 and lastly with one set to -30 and the other to 30 degrees.

It is well established that beams can be produced which are completely ‘unpolarized’ – that is, the proportion of ‘up’ to ‘down’ is always 50:50. Using such beams and setting both meters to the same plane, quantum theory predicts that the match between the meter readings will be perfect. That is to say an ‘up’ on the first meter will always correspond with an ‘up’ on the second and likewise ‘down’ with ‘down’ although the sequence of up and down appears to be unpatterned (i.e. random).

However, if one meter is set to 0 and the other to -30 (or 30) the perfect match is lost and the measured mismatch is 25%. From this one would expect that the mismatch when one meter is set to -30 and the other to 30 will not exceed 50%. Bell pointed out that this ‘classical’ expectation is not met by quantum systems, for when the meters are set to -30 and 30 the quantum prediction is that the mismatch will be 75%. Alain Aspect confirmed this prediction by setting up an experiment to perform these measurements.

How are we to interpret these results? It appears that the characteristics of the particles change as the meters are reset. This might be accepted and some ‘classical’ interpretation sought if it could be assumed that there is some means of communication between the meters such that setting them to -30 and 30 changes the environment for the particles in a way which changes their measured characteristics. The puzzle is that the distance between the meters can be arranged so that the effect of changing the setting of a meter must be transmitted faster than the speed of light to account for the observed results.

I have set up an APL model of this experiment which can be run in ‘classical’ or in ‘quantum’ mode. The model generates particle beams by creating a sequence of random numbers chosen from the set 0 0 1 3 4 6 7 7. The binary equivalent of these numbers represents the three characteristics of the particle which may be measured – that is to say whether it will be ‘up’(0) or ‘down’(1) at -30 0 30 degrees. Thus a particle represented by the number 6 (1 1 0) will give down at -30 and at 0 but up at 30 degrees. Similarly, a particle of number 7 (1 1 1) will give down at all settings while a particle of number 0 will give up at all settings, and so on.

The model prints a set of results for all the possible settings of the two meters. The number of particles (random sequences of numbers as described) between changes of meter settings can be chosen, as can the type of ‘reality’ – classical or quantum. The model prints for each meter the proportion of up to down measurements and the ‘mismatch’ ratio between meter A and meter B. If set to ‘classical’ the results are as expected – the mismatch at the -30 30 setting approximates to 0.5.

To simulate the quantum behaviour the model has a slight difference in coding when the meters are set to -30 30 (or 30 -30). In these cases the random sequence for the second meter is reset before display such that half (chosen at random) of all particles of number 0 (0 0 0) is reset to number 1 (0 0 1) and half (chosen at random) of all particles of number 7 (1 1 1) are reset to number 6 (1 1 0). This small change is all that is necessary to produce the quantum reality mismatch ratio of 0.75 and is the place where, as Nick Herbert would put it, ‘the miracle occurs’.

The fact that this resetting is done to all the numbers in the -30 30 and 30 -30 sequences represents the faster than light communication between the meters. To model the results which would be expected if the -30 30 setting were a significant change in the environment but that the effect could only be transmitted at the speed of light, the second meter sequence would be reset as described but after some delay. Therefore I have a third, modified, table of results which I have headed ‘M-QUANTUM’. The delay is represented in the model by excluding the first T particles from the ‘quantum resetting algorithm’ and this tends to reduce the mismatch ratio. The amount of the reduction depends on the ratio of T to the total number of particles S in the sequence. If S is 100 and T is 50 the mismatch ratio reduction will be 0.25 times T divide S which is a reduction of 0.125. If, however, T is small in relation to S the mismatch will be much less noticeable.

Let us imagine the model is run with this ‘propagation time’ adjustment. We have to consider what the effect would be if the first meter were now reset to measure the same characteristic as the second meter (say both set to 30 degrees). The change would have a propagation time which would be represented by continuing to reset T particles for the second meter as though during this ‘time’ the -30 30 settings still pertained and this would spoil the perfect match expected when both meters are set to measure the same characteristic. As before, the size of the blemish will depend on the ratio of T to S and will be a mismatch of 0.125 for T=50 and S=100. I have not simulated this as my model does not allow the settings to be changed while it is running.

What I do not yet know is whether Alain Aspect’s experiments are such as to exclude these possibilities of finding a ‘modified’ quantum effect. I doubt my ability yet to understand the paper in which it is described – but I’m working on it!

love,
Sylvia

    ∇ T BELL N
[1]  ⍝ Model of all possible meter pair
[2]  ⍝ settings for 0, 30 and ¯30 degrees
[3]  ⍝ for runs with sample size of N
[4]  ⍝ propagation time equivalent to sample T
[5]  ⍝
[6]   20 1⍴' '
[7]   ¯50↑'Reality is ''Classical'''
[8]   ' '
[9]   'C' UPDOWN N
[10]  SCREEN
[11]  ¯50↑'Reality is ''Quantum'''
[12]  'Q' UPDOWN N
[13]  SCREEN
[14]  ¯50↑'Reality is ''M-Quantum'''
[15]  'M' UPDOWN N,T
[16]  SCREEN
    ∇

    ∇ R←M MATCH S
[1]  ⍝ Match according to meter settings M
[2]  ⍝ returning mismatch ratio of sample S
[3]  ⍝
[4]   →(M='LRA')/LEFT,RIGHT,ACROSS
[5]  ⍝
[6]  LEFT:R←(+/S∊ 3 4)÷⍴S ⋄ →0
[7]  RIGHT:R←(+/S∊ 1 6)÷⍴S ⋄ →0
[8]  ACROSS:R←(+/S∊ 1 3 4 6)÷⍴S
    ∇

    ∇ R←QUANTUM S;N1;N2
[1]  ⍝ Changes members of sample S if
[2]  ⍝ 0 or 7 to 1 or 6
[3]  ⍝ half such members only are changed
[4]  ⍝ and they are chosen at random
[5]  ⍝
[6]   S[(S=0)/⍳⍴S]←(0 1)[?(+/S=0)⍴2]
[7]   S[(S=7)/⍳⍴S]←(7 6)[?(+/S=7)⍴2]
[8]   R←S
    ∇

    ∇ R←ROLL N
[1]  ⍝ Returns random sequence of N numbers
[2]  ⍝ chosen from 0 0 1 3 4 6 7 7
[3]  ⍝
[4]   R←(0 0 1 3 4 6 7 7)[?N⍴8]
    ∇

    ∇ SCREEN;A;B
[1]  ⍝ Print screen headings and results
[2]  ⍝ UDA and UDB are global vectors containing the meter up/down ratios
[3]  ⍝ CV is a global vector of the mismatch ratio of meter A and B readings
[4]  ⍝
[5]   (¯25↑'Meter A'),(¯20↑17↑'Mismatch Ratio'),'   Meter B'
[6]   (15↑'U:D Ratio'),(¯10↑'Angle'),(20↑' '),(10↑'Angle'),'U:D Ratio'
[7]   ' '
[8]   A← 0 30 ¯30 0 30 0 ¯30 ¯30 30
[9]   B← 0 30 ¯30 30 0 ¯30 0 30 ¯30
[10]  12 4 12 0 12 4 12 0 12 4 ⍕(UDA∘.+,0),(A∘.+,0),(CV∘.+,0),(B∘.+,0),UDB∘.+,0
    ∇

    ∇ R←T TQUANTUM S;N1;N2
[1]  ⍝ Makes random changes to members
[2]  ⍝ of sample S if member is 0 or 7
[3]  ⍝ in the same way as function QUANTUM
[4]  ⍝ but excluding first T of S
[5]  ⍝ to simulate propagation time
[6]  ⍝
[7]   R←T↓S
[8]   R[(R=0)/⍳⍴R]←(0 1)[?(+/R=0)⍴2]
[9]   R[(R=7)/⍳⍴R]←(7 6)[?(+/R=7)⍴2]
[10]  R←(T↑S),R
    ∇

    ∇ TYP UPDOWN N;S;T
[1]  ⍝ Determine the 'up/down' ratio
[2]  ⍝ of the polarity of the samples
[3]  ⍝
[4]   T←¯1↑N ⋄ N←1↑N ⋄ UDA←UDB←CV←⍳0
[5]  ⍝
[6]   UDA←UDA,(+/(ROLL N)∊ 0 1 4)÷N
[7]   UDA←UDA,(+/(ROLL N)∊ 0 4 6)÷N
[8]   UDB←UDA←UDA,(+/(ROLL N)∊ 0 1 3)÷N ⋄ CV←3⍴0
[9]   UDA←UDA,(+/(S←ROLL N)∊ 0 1 4)÷N
[10]  UDB←UDB,(+/S∊ 0 4 6)÷N ⋄ CV←CV,'R' MATCH S
[11]  UDA←UDA,(+/(S←ROLL N)∊ 0 4 6)÷N
[12]  UDB←UDB,(+/S∊ 0 1 4)÷N ⋄ CV←CV,'R' MATCH S
[13]  UDA←UDA,(+/(S←ROLL N)∊ 0 1 4)÷N
[14]  UDB←UDB,(+/S∊ 0 1 3)÷N ⋄ CV←CV,'L' MATCH S
[15]  UDA←UDA,(+/(S←ROLL N)∊ 0 1 3)÷N
[16]  UDB←UDB,(+/S∊ 0 1 4)÷N ⋄ CV←CV,'L' MATCH S
[17]  →(TYP='CQM')/REALC,REALQ,REALM
[18] REALC:
[19]  UDA←UDA,(+/(S←ROLL N)∊ 0 1 3)÷N
[20]  UDB←UDB,(+/S∊ 0 4 6)÷N ⋄ CV←CV,'A' MATCH S
[21]  UDA←UDA,(+/(S←ROLL N)∊ 0 4 6)÷N
[22]  UDB←UDB,(+/S∊ 0 1 3)÷N ⋄ CV←CV,'A' MATCH S ⋄ →0
[23] REALQ:
[24]  UDA←UDA,(+/(S←ROLL N)∊ 0 1 3)÷N
[25]  UDB←UDB,(+/(S←QUANTUM S)∊ 0 4 6)÷N ⋄ CV←CV,'A' MATCH S
[26]  UDA←UDA,(+/(S←ROLL N)∊ 0 4 6)÷N
[27]  UDB←UDB,(+/(S←QUANTUM S)∊ 0 1 3)÷N ⋄ CV←CV,'A' MATCH S ⋄ →0
[28] REALM:
[29]  UDA←UDA,(+/(S←ROLL N)∊ 0 1 3)÷N
[30]  UDB←UDB,(+/(S←T TQUANTUM S)∊ 0 4 6)÷N ⋄ CV←CV,'A' MATCH S
[31]  UDA←UDA,(+/(S←ROLL N)∊ 0 4 6)÷N
[32]  UDB←UDB,(+/(S←T TQUANTUM S)∊ 0 1 3)÷N ⋄ CV←CV,'A' MATCH S
    ∇